| Usuario |
ejecutar exe en vb |
Desconocido
|
| Enviado - 17/11/2004 |
| ? |
Existe esta funcion
Shell "C:\prueba.exe",vbNormalFocus
para ejecutar un archivo exe desde visual basic pero hay alguna manera para que la ejecucion del programa vb no continue hasta que cerremos el exe lanzado.
Saludos
|
| ? |
|
l_island
110 Mensaje(s)
|
| Enviado - 17/11/2004 |
| ? |
Aqu? tienes un ejemplo de como hacer lo que quieres:
'make a batch file (.bat) in "c:\" and name it "Test.bat", inside just
'write "pause". Your script will wait until you have pushed a button
'before ending. Now instead of the batch file, put the application you wish
'to run and you wish VB to wait for.
'Declarations:
Private Type STARTUPINFO
cb As Long
lpReserved As String
lpDesktop As String
lpTitle As String
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As Long
hStdError As Long
End Type
Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessID As Long
dwThreadID As Long
End Type
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal _
hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
lpStartupInfo As STARTUPINFO, lpProcessInformation As _
PROCESS_INFORMATION) As Long
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long
Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const INFINITE = -1&
Private Sub Form_Load()
Dim retval as Long
retval = ExecCmd("c:\test.bat")
End
End Sub
Public Function ExecCmd(cmdline$) As Long
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim ret as Long
start.cb = Len(start)
ret& = CreateProcessA(0&, cmdline$, 0&, 0&, 1&, NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)
'Wait for the shelled application to finish:
ret& = WaitForSingleObject(proc.hProcess, INFINITE)
Call GetExitCodeProcess(proc.hProcess, ret&)
Call CloseHandle(proc.hThread)
Call CloseHandle(proc.hProcess)
ExecCmd = ret&
End Function
La encontr? en la red y funciona.
Saludos!!
l_island |
| ? |
|
|
|
